BASIC-Befehl INPUT
Der "INPUT"-Befehl in BASIC ermöglicht die Eingabe von Daten innerhalb eines Programms. Vor der Eingabe wird ein Kommentar angezeigt, der optional ist. Danach wird ein Fragezeichen (?) als Aufforderung angezeigt, um dem Benutzer zu signalisieren, dass eine Eingabe erwartet wird. Der blinkende Cursor zeigt an, wo die Eingabe erfolgen soll. Sobald die Eingabe abgeschlossen ist und die RETURN-Taste gedrückt wurde, werden die Daten in Variablen gespeichert. Es können sowohl Zeichenketten- als auch Zahlvariablen verwendet werden.
10 INPUT A$
20 PRINT A$

Bestimmte Zeichen haben bei der Eingabe innerhalb des INPUT-Befehls eine besondere Funktion.
Das Komma (,) wird beispielsweise verwendet, um mehrere Eingabewerte zu trennen, wenn mehrere Variablen in einem INPUT-Befehl angegeben werden sollen. Um eine Eingabe zu ermöglichen, die das Komma als Teil des Texts enthält, können Anführungszeichen verwendet werden, um dies zu umgehen.
Der Doppelpunkt (:) bewirkt, dass alle nachfolgenden Zeichen in der Eingabe ignoriert werden. Wenn ein Doppelpunkt als Teil des Eingabetexts benötigt wird, kann dieser durch Verwendung von Anführungszeichen umgangen werden.
Leerzeichen vor dem ersten Zeichen werden ignoriert, es sei denn, sie folgen auf ein Komma oder einen Doppelpunkt. In diesen Fällen bleiben sie erhalten. Wenn ein Leerzeichen als Teil des Eingabetexts benötigt wird, kann auch hier die Verwendung von Anführungszeichen dazu genutzt werden, dies zu umgehen.
Wenn die Eingabe mit Anführungszeichen (") beginnt (außer es folgt ein Leerzeichen), kann dies auch die Eingabe von Kommas und Doppelpunkten ermöglichen. Es ist nicht unbedingt erforderlich, dass die Eingabe mit einem Anführungszeichen endet, aber wenn ein Anführungszeichen verwendet wird, muss es sich am Ende der Eingabe befinden. Andernfalls wird nach der Fehlermeldung "?REDO FROM START" erneut die Eingabe aufgefordert.

Wenn der Kommentarparameter im INPUT-Befehl darauf hinweist, dass mehrere Dateneingaben erwartet werden, können Benutzer die geforderten Dateneingaben bereits durch Kommas (
,) getrennt eingeben. Dadurch wird das Verhalten vermieden, bei dem der
INPUT-Befehl mit Doppelfragezeichen (
??) auf weitere erforderliche Dateneingaben hinweist und erneut auf deren Eingabe wartet.
Falls jedoch zu viele Daten durch Kommas (
,) getrennt eingegeben werden, wird die BASIC-Meldung "
?EXTRA IGNORED" ausgegeben, aber das Programm wird trotzdem fortgesetzt. Das bedeutet, dass die zu viel eingegebenen Daten ignoriert und nicht in den Variablen abgespeichert werden. Es ist daher ratsam, die richtige Anzahl von Eingaben bereitzustellen, um das Programm ordnungsgemäß auszuführen.
Link:
www.c64-wiki.de INPUThttps://www.c64-wiki.de/wiki/INPUT
für weitere Informantionen
https://www.c64-wiki.de/wiki/INPUT
BASIC-Befehl INPUT#
Der INPUT#-Befehl ermöglicht das Einlesen von Daten aus einem Peripheriegerät, wie beispielsweise einem Datasetten- oder Diskettenlaufwerk, innerhalb von BASIC-Programmen. Dabei liest der INPUT#-Befehl die Daten als eine Zeichenfolge ein (nicht als einzelne Zeichen) und ordnet sie entsprechend den angegebenen Variablen zu, basierend auf den verwendeten Trennzeichen. Der Eingabebereich ist auf maximal 88 Zeichen begrenzt.
Wir wollen mal den kompletten Bildschirm in einer Variable speichern und ausgeben.
10 DIM A$(25)
20 PRINT CHR$(19); : REM HOME-BILDSCHIRMPOSITION
30 OPEN 1,3 : REM BILDSCHIRM GERAET
40 FOR X=1 TO 25: INPUT#1,A$(X): NEXT X
50 CLOSE 1
60 PRINT CHR$(147);
70 FOR X=1 TO 24: PRINT A$(X): NEXT X
80 PRINT A$(25) CHR$(19)
Hier finden wir neue Funktionen wie OPEN 1,3 und CLOSE 1. Ich werde später näher darauf eingehen, aber vorerst genügt es zu wissen, dass die Zahl 1 den Kanal und die Zahl 3 den Bildschirm angibt. Wir öffnen also über Kanal 1 eine Verbindung zum Bildschirm 3 und verarbeiten die Information dann in einer FOR-Schleife. Mit INPUT#1 lesen wir die gesamte Zeile ein und speichern sie in der Array-Variable A$(X). Nach Abschluss der Schleife schließen wir die Verbindung wieder mit CLOSE 1 für Kanal 1.
Ab Zeile 60 leeren wir den Bildschirm und geben die Arrayvariable wieder aus.


Aber was ist denn jetzt passiert? Es fehlen doch Informationen!
Beim Einlesen von Variablen (Zeichenketten- oder Zahlenvariablen) wird der Datensatz jeweils durch ein Trennzeichen beendet. Diese Trennzeichen können sein:
Komma (
,)
Semikolon (
;)
Doppelpunkt (
:)
RETURN-Zeichen -
CHR$(13)Diese Trennzeichen werden als Bestandteil der Daten selbst betrachtet und können nur innerhalb von Anführungszeichen (
"") als String in die Variablen gelangen. Nach dem Einlesen ist nicht mehr feststellbar, welches Trennzeichen tatsächlich vorlag, da diese nicht durchgereicht werden.
Wenn die einzulesende Zeile mit einem Anführungszeichen (
") also
CHR$(34) oder einem
RETURN-Zeichen beginnt, können auch die oben genannten Trennzeichen "
:,;" enthalten sein. Allerdings muss die Zeile mit einem Anführungszeichen oder einem
RETURN-Zeichen enden. Wenn jedoch weitere Zeichen folgen (außer den oben genannten Trennzeichen), wird der Befehl mit dem Fehler "
?FILE DATA ERROR" abgebrochen.
Link:
www.c64-wiki.de INPUT#https://www.c64-wiki.de/wiki/INPUT(Raute)
für weitere Informantionen
https://www.c64-wiki.de/wiki/INPUT(Raute)
Basic-Befehl GET
Der
GET-Befehl liest einzelne Zeichen des Tastaturpuffers in eine Variable (Zeichenketten-, Fließkomma- oder Ganzzahlvariable) ein und kann nur innerhalb von BASIC-Programmen, nicht im Direktmodus, genutzt werden. Nach dem Auslesen eines Zeichens ist im Tastaturpuffer wieder Platz für ein weiteres Zeichen. Der Tastaturpuffer des C64 hat Platz für maximal 10 Zeichen und ignoriert alle darüberhinausgehenden Eingaben. Der Befehl blockiert nicht, sondern kehrt sofort mit einem Ergebnis zurück. Falls keine Taste gedrückt ist und der Tastaturpuffer leer ist, enthält eine Zahlenvariable den Wert 0, eine Zeichenkettenvariable den Leerstring.
Bei Verwendung einer Zahlenvariable im
GET-Befehl und Eingabe eines nicht-numerischen Zeichens wie
+,
-, oder
. wird der BASIC-Fehler
?SYNTAX ERROR ausgegeben. Bei Eingabe von
, oder
: wird die Meldung
?EXTRA IGNORED ausgegeben, ohne das Programm abzubrechen. Zur Vermeidung solcher Fehlermeldungen samt Programmabbruch sollte stets eine Zeichenkettenvariable zum Einlesen von der Tastatur genutzt werden. Wenn der
GET-Befehl im
Direktmodus
Der Direktmodus ist ein Betriebsmodus in BASIC, der es ermöglicht, BASIC-Befehle direkt an den Computer zu senden, ohne dass sie zuvor in ein BASIC-Programm eingegeben werden müssen. Im Direktmodus können Befehle sofort ausgeführt und Ergebnisse angezeigt werden. Es ist ein nützliches Werkzeug für die Fehlerbehebung und zum Ausprobieren von Befehlen und Funktionen, ohne ein vollständiges Programm schreiben zu müssen. z.B.PRINT 5+1 genutzt wird, erscheint die BASIC-Fehlermeldung
?ILLEGAL DIRECT ERROR.
Mit dem
GET-Befehl können benutzerdefinierte Eingaberoutinen entwickelt werden, die einige Nachteile des
INPUT-Befehls beheben.
10 PRINT "GEBEN SIE BITTE MAX. 20 ZEICHEN EIN: ":GOSUB 1020
20 PRINT: PRINT "SIE HABEN EINGEGEBEN: ";B$
30 END
1000 REM EINFACHE GET-EINGABEROUTINE
1010 REM INITALISIEREN DER BENUTZTEN VARIABLEN
1020 A$="": B$="": A=0
1030 GET A$: IF A$="" THEN 1030
1040 A=ASC(A$): IF ( A<32 OR A>127 ) AND A<>13 THEN 1030
1050 B$=B$+A$: PRINT A$;: IF LEN(B$)<20 AND A$<>CHR$(13) THEN 1030
1060 RETURN
Die Zeilen
10 bis
30 werde ich nicht erklären, die sollten sich von selbst erklären😇.
In Zeile
1020 werden, sofern sie noch nicht existieren, Variablen erstellt und mit Startwerten belegt.
In Zeile
1030 wird mit dem Befehl
GET das erste Zeichen aus dem Tastaturpuffer abgerufen und in der Variable
A$ gespeichert. Anschließend wird geprüft, ob
A$ den Leerstring enthält. Ist dies der Fall, wird mit
IF A$="" THEN 1030 wieder zurück zur Zeile
1030 gesprungen, um auf eine Eingabe zu warten.
IST A$ gleich leer DANN springe wieder zum Anfang der Zeile. Wenn nicht leer, führe den Code weiter aus.
In Zeile
1040 wird mit
A=ASC(A$) das Zeichen aus dem Tastaturpuffer in PETSCII-Code umgewandelt und in der Variablen
A gespeichert. Anschließend wird überprüft, ob das eingegebene Zeichen erlaubt ist:
IF ( A<32 OR A>127 ) AND A<> 13 THEN 1030IST ( A kleiner als 32 ODER A größer als 127) UND A NICHT GLEICH(<>) RETURN DANN springe zu Zeile 1030. Wenn Zeichen erlaubt, führe den Code weiter aus.In Zeile
1050 wird mit
B$=B$+A$ das erlaubte Zeichen immer an die Stringvariable
B$ angehängt. Anschließend wird das Zeichen mit
PRINT A$; ausgegeben, wobei das Semikolon(
;) dafür sorgt, dass der Cursor nach der Ausgabe auf dem Bildschirm an derselben Stelle bleibt.
Mit
IF LEN(B$) < 20 AND A$ <> CHR$(13) THEN 1030IST DIE LÄNGE VON(B$) KLEINER ALS 20 UND A$ NICHT GLEICH RETURN DANN spring zu 1030Mit der Zeile
1060 wird das Unterprogramm beendet und mit
RETURN zum Aufrufpunkt zurückgekehrt, also in diesem Fall in Zeile
10 nach
GOSUB 1020. Von dort aus wird das Programm fortgesetzt.
Link:
PETSCII / "PET Standard Code of Information Interchange"https://www.c64-wiki.de/images/2/20/ASCII-Codes.gifLink:
www.c64-wiki.de GETFür weitere Informantionen
https://www.c64-wiki.de/wiki/GET

Basic-Befehl GET#
Der BASIC-Befehl GET# liest ein einzelnes Zeichen aus dem Gerät ein, das der logischen Dateinummer zugeordnet ist. Das Gerät kann beispielsweise ein Datenkanal oder eine geöffnete Datei sein.
Bevor der GET#-Befehl genutzt werden kann, muss das entsprechende Gerät oder die Datei mit dem BASIC-Befehl OPEN geöffnet werden. Dabei muss die entsprechende logische Dateinummer des OPEN-Befehls verwendet werden. Falls die Dateinummer nicht geöffnet ist, führt dies zu einem Programmabbruch mit der Fehlermeldung ?FILE NOT OPEN. Diese Fehlermeldung tritt auch auf, wenn die an sich nicht verwendbare Dateinummer 0 genutzt wird. Die Dateinummer darf sonst nur Werte von 1 bis 255 annehmen, andernfalls wird der BASIC-Fehler ?ILLEGAL QUANTITY ERROR ausgegeben.
Das eingelesene Zeichen wird in einer Variablen (Zeichenketten-, Fließkomma- oder Ganzzahlvariable) abgelegt. Das Verhalten von GET# ähnelt dem von GET, weicht jedoch in Details ab.
Vom Bildschirm "einlesen"
255 Bildschirmzeichen in einer Zeichenkette speichern.
10 PRINT CHR$(19);: B$="": OPEN 1,3
20 FOR I=1 TO 255
30 GET#1,A$: B$=B$+A$
40 NEXT
50 CLOSE 1
60 PRINT "" CHR$(147) B$
Von Tastatur ähnlich GET einlesen:Dieses Programm liest ähnlich wie
GET Zeichen von der Tastatur ein, allerdings können nur Ziffern von 1 bis 9 eingelesen werden.
10 OPEN 1,0 : REM GERAET 0 = TASTATUR
20 GET#1,A: IF A=0 GOTO 20
30 PRINT A;
40 GOTO 20
Es sollte beachtet werden, dass das Zeichen "0" den gleichen Wert wie keine Eingabe hat und nicht davon unterschieden werden kann. Außerdem werden einige Sonderzeichen, wie ",", ".", "-", "+", "e", ignoriert und liefern den Wert 0, während alle anderen Zeichen zu einem Syntaxfehler ?SYNTAX ERROR führen und das Programm abbrechen lassen